/////////(Copyright)//////(No modificar estas 11 primeras Lineas)/////////
//     Autor: Antonio Castro Snurmacher (E-mail  )
//
//  Este fuente puede ser utilizado, distribuido, y modificado libremente
//  pero siempre se deberá respetar la propiedad intelectual de su autor.
//  El autor renuncia a todo tipo de beneficio económico y no se hace
//  responsable de los posibles perjuicios derivados del uso del mismo.
//  Toda modificación queda sujeta a las mismas condiciones de uso que el
//  original. En caso de traducción deberá conservarse el texto original
//  de esta cabecera y añadirse la traducción a continuación de ella.
//////////////////////////////////////////////////////////////////////////

//-----------------------------------------------------------------------
//     balistap.inc  (1-Mayo-1998)
//-----------------------------------------------------------------------
//  Esta versión esta dedicada a su inclusión en la revista LinuxFocus
//-----------------------------------------------------------------------


#declare Color1    = color red 0.5  green 0.2  blue 0.4;
#declare ColorEye  = color red 0.5  green 0.5  blue 0.5;

// Aleta inferior
#declare AletDown =
intersection {
   sphere { <-10,-7,0> 10 
         scale <2, 1, 0.1>
   }
   sphere { <-15,-17,0> 10 
         scale <2, 1, 1>
        inverse
   }
   cone { <-10, 0, 0>, 0 <-45, 0, 0>, 20 inverse }
   pigment { color Color1 }
}

// Aleta superior
#declare AletUp =
intersection {
   sphere { <-10,7,0>, 10 
         scale <2, 1, 0.1>
   }
   sphere { <-15, 17,0>, 10 
         scale <2, 1, 1>
         inverse
   }
   cone { <-10, 0, 0>, 0 <-45, 0, 0>, 20 inverse }
   pigment { color Color1 }
}

// Aleta caudal (cola)
#declare Tail =
intersection {
   sphere { <-19,0,0>, 10 
         scale <2, 1, 0.1>
   }
   sphere { <-25,0,0>, 10 
         scale <2, 1.3, 1>
        inverse
   }
   pigment { color Color1 }
}

// Pez completo 
#declare Balistap =
union{
   sphere { <10, 4,0>,4 
      pigment { color ColorEye }
         scale <1,1, 0.6>
   }
   sphere { <10.2, 4.35,0>,3.43
      pigment { color Gray20 }
         scale <1,1, 0.7>
   }
   sphere { <0,0,0> 10 
         scale <2, 1, 0.3>
        pigment { 
           gradient y 
           colour_map {
                [0.0  colour White]
                [0.1  colour Grey]
                [0.99  colour Black]
           }
          scale <1, 17, 1>
          translate <0, -7, 0>
        }
   }

   cone {<19, 0, 0>, 1.5 <-2, 0, 0> 8
        scale <1,1, 0.5>
        pigment { color Color1 }
   }
   cone {<21, 0, 0>, 1 <0, 0, 0> 13
        scale <1,1, 0.1>
        pigment { color Color1 }
   }
  object {AletUp}
  object {AletDown}
  object {Tail}
}